|

Проект «Калькулятор на Arduino с дисплеем LCD1602 и клавиатурой 4х4»

Всем привет! 😊

Вот новый интересный проект на Arduino — калькулятор с дисплеем lcd1602 и клавиатурой из 16 клавиш.

Проект взят из Интернета, доработан под I2C версию дисплея, а также добавлены комментарии в код для тех, кто хочет изучить работу скетча.

Вот готовый код с комментариями:

#include <Adafruit_LiquidCrystal.h>
#include <Keypad.h>

/* Подключаем программно дисплей */
Adafruit_LiquidCrystal lcd(0);

/* Подключаем программно клавиатуру */
const byte KEYPAD_ROWS = 4;
const byte KEYPAD_COLS = 4;
byte rowPins[KEYPAD_ROWS] = {5, 4, 3, 2};
byte colPins[KEYPAD_COLS] = {A3, A2, A1, A0};
char keys[KEYPAD_ROWS][KEYPAD_COLS] = {
  {'1', '2', '3', '+'},
  {'4', '5', '6', '-'},
  {'7', '8', '9', '*'},
  {'.', '0', '=', '/'}
};
// Конфигурируем клавиатуру в библиотеке
Keypad keypad = Keypad(makeKeymap(keys), rowPins, colPins, KEYPAD_ROWS, KEYPAD_COLS);

uint64_t value = 0;

// Приветственный экран - функция
void showSpalshScreen() {
  lcd.print("@arduino-uno-ws");
  lcd.setCursor(3, 1);
  String message = "Calculator";
  for (byte i = 0; i < message.length(); i++) {
    lcd.print(message[i]);
    delay(50);
  }
  delay(500);
}
// Мигание курсором - функция
void updateCursor() {
  if (millis() / 250 % 2 == 0 ) {
    lcd.cursor();
  } else {
    lcd.noCursor();
  }
}

// Начинаем
void setup() {
  Serial.begin(115200); // Сериал на скорости 115200 бод
  lcd.begin(16, 2); // Размеры дисплея 16 симв. 2 строки

  showSpalshScreen(); // Приветствуем
  lcd.clear(); // Очищаем экран
  lcd.cursor();  // Ставим курсор

  // Ставим курсор на Первом символе (по факту втором) и Нулевой строке (по факту - первой)
  lcd.setCursor(1, 0);
}

 // Создаём переменные
char operation = 0;
String memory = "";
String current = "";
uint64_t currentDecimal;
bool decimalPoint = false;

 // Калькуляция
double calculate(char operation, double left, double right) {
  switch (operation) {
    case '+': return left + right;
    case '-': return left - right;
    case '*': return left * right;
    case '/': return left / right;
  }
}

 // Ввод чисел
void processInput(char key) {
  if ('-' == key && current == "") {
    current = "-";
    lcd.print("-");
    return;
  }
 // Вывод чисел
  switch (key) {
    case '+':
    case '-':
    case '*':
    case '/':
      if (!operation) {
        memory = current;
        current = "";
      }
      operation = key;
      lcd.setCursor(0, 1);
      lcd.print(key);
      lcd.setCursor(current.length() + 1, 1);
      return;

    case '=':
      float leftNum = memory.toDouble();
      float rightNum = current.toDouble();
      memory = String(calculate(operation, leftNum, rightNum));
      current = "";
      lcd.clear();
      lcd.setCursor(1, 0);
      lcd.print(memory);
      lcd.setCursor(0, 1);
      lcd.print(operation);
      return;

  }

  if ('.' == key && current.indexOf('.') >= 0) {
    return;
  }

  if ('.' != key && current == "0") {
    current = String(key);
  } else if (key) {
    current += String(key);
  }

  lcd.print(key);
}

 // Цикл
void loop() {
  updateCursor();

  char key = keypad.getKey();
  if (key) {
    processInput(key);
  }
}

Приведённый выше код нужно просто вставить в .ino файл и залить его в Arduino.

Подключение дисплея и клавиатуры к Arduino

Пин модуля > пин Arduino

Дисплей LCD1602:

  • SDA > SDA
  • SCL > SCL
  • VCC > 5V
  • GND > GND

Клавиатура 4х4:

  • Row 1 > D5
  • Row 2 > D4
  • Row 3 > D3
  • Row 4 > D2
  • Column 1 > A3
  • Column 2 > A2
  • Column 3 > A1
  • Column 4 > A0

Схема подключения:

Просмотр схемы и симуляция в Tinkercad.

Скачать библиотеку для дисплея.

5/5 - (19 голосов)


Поделись!